vulkan: fix build dependency issue with generated files

On machines with many cores, you can run into that issue :

../mesa-9999/src/vulkan/overlay-layer/overlay.cpp:42:10: fatal error: vk_enum_to_str.h: No such file or directory

v2: Move declare_dependency around (Eric)

Signed-off-by: Lionel Landwerlin <lionel.g.landwerlin@intel.com>
Reported-by: Jan Ziak
Cc: <mesa-stable@lists.freedesktop.org>
Reviewed-by: Eric Engestrom <eric.engestrom@intel.com>

src/vulkan/meson.build

@@ -20,7 +20,6 @@
 
 vk_api_xml = files('registry/vk.xml')
 
-inc_vulkan_util = include_directories('util')
 inc_vulkan_wsi = include_directories('wsi')
 
 vulkan_wsi_args = []

src/vulkan/overlay-layer/meson.build

@@ -41,10 +41,10 @@ vklayer_mesa_overlay = shared_library(
   vklayer_files, overlay_spv,
   c_args : [c_vis_args, no_override_init_args, vulkan_wsi_args],
   cpp_args : [cpp_vis_args, vulkan_wsi_args],
-  dependencies : [vulkan_wsi_deps, libimgui_core_dep, dep_dl],
-  include_directories : [inc_common, inc_vulkan_util],
+  dependencies : [idep_vulkan_util, vulkan_wsi_deps, libimgui_core_dep, dep_dl],
+  include_directories : inc_common,
   link_args : cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions', '-Wl,-z,relro']),
-  link_with : [libmesa_util, libvulkan_util],
+  link_with : libmesa_util,
   install : true
 )
 

src/vulkan/util/meson.build

@@ -44,3 +44,15 @@ libvulkan_util = static_library(
   c_args : [c_vis_args, vulkan_wsi_args],
   build_by_default : false,
 )
+
+idep_vulkan_util_headers = declare_dependency(
+  sources : vk_enum_to_str[1],
+  include_directories : include_directories('.')
+)
+
+idep_vulkan_util = declare_dependency(
+  sources : vk_enum_to_str[1],
+  link_with : libvulkan_util,
+  include_directories : include_directories('.'),
+  dependencies : idep_vulkan_util_headers
+)

src/vulkan/wsi/meson.build

@@ -41,9 +41,9 @@ endif
 libvulkan_wsi = static_library(
   'vulkan_wsi',
   files_vulkan_wsi,
-  include_directories : [inc_common, inc_vulkan_util, inc_include],
+  include_directories : [inc_common, inc_include],
   link_with: [libxmlconfig],
-  dependencies : [vulkan_wsi_deps, dep_libdrm],
+  dependencies : [vulkan_wsi_deps, dep_libdrm, idep_vulkan_util],
   c_args : [c_vis_args, vulkan_wsi_args],
   build_by_default : false,
 )